Main Page
Introduction
ClaG: classification of games for toy libraries and libraries
As of August 2024, Cla-G, this Wikibase instance, has been created and gradually enriched with linked data related to ‘’ClaG. Classification of games for playrooms and libraries‘’ by Carlo Bianchini and Paolo Munini. The proposal was presented:
- as part of the fair Modena Play in May 2024 and
- at the Department of Musicology and Cultural Heritage of the University of Pavia, based in Cremona.
The dataset, in line with our values, is aimed to grow on the basis of the collaboration of the volunteers participating in the project and is a tool available free of charge to all the toy libraries and libraries that want to adopt and use ClaG as a classification. This means that our dataset is a ‘growing organism’ and that, at all times, its form is to be considered provisional and perfectible.
Objectives
The purpose of Cla-G can be summarised, not necessarily exhaustively, by referring to three possible areas of interest: that of a specific institution, that of a toy library or library manager and that of general knowledge of the world of games.
With respect to an institution (a toy library or library), the advantages of using Cla-G may be:
- having a collaborative and participatory classification tool available among all the toy libraries and libraries involved;
- the possibility of creating, downloading, sharing, publishing a complete, navigable and interactive list of the games in one's collection;
- using an advanced LOD-based tool that allows reciprocal navigation between one's OPAC and Cla-G as well as between one's OPAC and Wikidata;
- increase, through the logic of LODs, the visibility and discovery possibilities of one's own collection of games;
- create a network of people, associations and institutions engaged in this field and foster the development of cooperation and exchange of information between them.
From the point of view of the toy library and library manager, Cla-G is an effective tool for:
- classify the games in one's collection in an easy way, through the guided process of producing a class number;
- to physically organise one's collection of games in the available spaces;
- have ClaG's classification schedules available in a complete, free and constantly updated form;
- learning to analyse a game in its fundamental characteristics;
- manage reference interaction in a professional way, more easily retrieving games that have the characteristics required by players entering the toy library or library;
- consult the class number assigned to a game by another institution;
- find out which and how many institutions own a given game.
Finally, Cla-G will be a very useful tool for knowledge of games in general, because it will allow:
- provide a free and free consultation tool for the discovery of existing games (i.e. owned by all participating institutions);
- offer a tool for discovering and exploring games according to their characteristics (game space, materials, setting, outcome, genre and age);
- create a dataset enabling quantitative analysis of games produced by the market;
- improve the ability to check and verify, and thus the quality, of games data;
- encourage the re-use of data on games and their ClaG classification number.
Volunteers Involved
This section records the names of all the volunteers and institutions who collaborate in various ways in the creation and maintenance of ClaG data. The registration of participants has the dual function of recognising the work done by each one and of enabling the quality of the contributions made to be checked (by following the link ‘see changes’).
- Carlo Bianchini (Vedi modifiche)
- Camillo Pellizzari (Vedi modifiche)
- Claudia Mauro (AIG) (Vedi modifiche)
- Paolo Munini (Vedi modifiche)
- UgoScala (Vedi modifiche)
- SCUP in servizio alla Biblioteca comunale di Trento (Vedi modifiche)
How to start exploring Cla-G
Here are some starting points to get started with the contents of this wiki:
- Search for a few games you expect to find (by entering the name in the box at the top right).
- Use some of the following ready-made queries to get an idea of the data collected and the advantages of organising the games according to the number of Cla-Gs:
All games in alphabetical order
#title:All games in alphabetical order
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All tabletop games without other support in alphabetical order
#title:All tabletop games without other support in alphabetical order
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P17 ld:Q41 .
# OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All solitaire games classified in the dataset
#title:All solitaire games classified in the dataset
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass ?item WHERE {
?item ldt:P21 ld:Q111 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All traditional and special dice games classified in the dataset
#title:All traditional and special dice games classified in the dataset
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass ?item WHERE {
{ ?item ldt:P18 ld:Q75 .} UNION { ?item ldt:P18 ld:Q76 . } UNION { ?item ldt:P18 ld:Q77 . }
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All games in alphabetical order owned by the Trento Public Library
#title:All games in alphabetical order owned by the Trento Public Library
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P26 ld:Q187 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All games in alphabetical order recorded in Cla-G but missing at the Trento Public Library
#title:All games in alphabetical order ''recorded in Cla-G but missing at'' the Trento Public Library
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
FILTER NOT EXISTS { ?item ldt:P26 ld:Q187 . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All games in alphabetical order owned by the Udine municipal toy library
#title:All games in alphabetical order owned by the Udine municipal toy library
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P26 ld:Q196 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
All games in alphabetical order having one or more OPAC SBN FVG IDs
#title:All games in alphabetical order having one or more OPAC SBN FVG IDs
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?numClass ?item ?itemDescription ?sbnfvgID WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P25 ?ID .
BIND(uri(concat("https://www.sbnfvg.it/?IDS=", ?ID)) as ?sbnfvgID)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Linking ClaG to a library catalogue
Even though we know that cataloging and classification are very different, this does not mean that you cannot connect the item of a game classified on ClaG with its description in a library catalog.
A main feature of ClaG is that it was designed to be used - independently from the catalogue - to enable the physical organization of the collections and to help the librarian in the reference service, but it can also be integrated in the catalogue record.
Dobble is an example of how
- an item of ClaG can be connected to the SBN FVG catalog (click on the number 664647 corresponding to the property SBNFVG game ID)
- the Dobble catalog entry can be linked to Dobble item in ClaG (click on "ClaG: visualizza la risorsa su Wikibase" in the ClaG section of the entry).
So, Cla-G and the OPAC of an institution can be interlinked and enable the reader to easily navigate back and forward.
Advanced Queries
If you want to extract more data, or more complex data, or a data visualization, you can try one of these queries:
Visualisation of the model with tree graphs
Tree graph of subclasses of play (full ontology)
#title:Tree graph of subclasses of play
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q3 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q2) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Tree graph of subclasses according to space
#title:Tree graph of subclasses according to space
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q23 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q23) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Tree graph of subclasses according to materials
#title:Tree graph of subclasses according to materials
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q58 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q58) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Tree graph of subclasses according to setting
#title:Tree graph of subclasses according to setting
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q91 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q91) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Tree graph of subclasses according to outcome
#title:Tree graph of subclasses according to outcome
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q104 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q104) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Tree graph of subclasses according to genre
#title:Tree graph of subclasses according to genre
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q122 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q3) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Count Queries
Amount of games according to genre arranged by genre class
#title: Amount of games according to genre arranged by genre class
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?genere ?genereLabel (COUNT(?item) AS ?count) WHERE {
?item ldt:P1 ld:Q4 . #Q4 è un gioco
?item ldt:P22 ?genere.
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?genere ?genereLabel
ORDER BY ASC(?genereLabel)
Bar Chart of games according to genre arranged by genre class
#title: Amount of games according to genre arranged by genre class
#defaultView:BarChart
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?genere ?genereLabel (COUNT(?item) AS ?count) WHERE {
?item ldt:P1 ld:Q4 . #Q4 è un gioco
?item ldt:P22 ?genere.
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?genere ?genereLabel
ORDER BY ASC(?genereLabel)
ClaG class numbers according to decreasing amount of plays and games linked
#title: ClaG class numbers according to decreasing amount of plays and games linked
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?numClass (COUNT(?item) AS ?count) WHERE {
?item ldt:P1 ld:Q4 . #Q4 è un gioco
?item ldt:P24 ?numClass .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?numClass ?numClassLabel
ORDER BY DESC(?count)
Federated Query with Wikidata
Plays and games which have an image in Wikicommons but not in Cla-G
#title: Plays and games which have an image in Wikicommons but not in Cla-G
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?wdlink ?wditem ?image WHERE {
?item ldt:P1 ld:Q4 . #Q4 Gioco
?item ldt:P3 ?wdlink . # Ricava l'ID del gioco in WD
FILTER NOT EXISTS { ?item ldt:P28 ?immagineClaG . }
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P18 ?image . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
Query to check data quality
List of items missing English label (if any)
# English and Italian labels
#title: List of items missing English label
SELECT DISTINCT ?item ?LabelIT ?LabelEN WHERE {
?item ?p ?o .
?item rdfs:label ?LabelIT FILTER (lang(?LabelIT) = "it") .
FILTER NOT EXISTS { ?item rdfs:label ?LabelEN FILTER (lang(?LabelEN) = "en") . }
}
List of classes and their English label and description (if any)
#title:List of classes and their label and description
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?itemDescription WHERE {
?item ldt:P2* ld:Q3 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q2) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?itemLabel
ClaG's Glossary
The Proposta per una classificazione dei giochi ad uso di Ludoteche e Biblioteche [i.e. Proposal for a classification of games for use in toy libraries and Libraries] published in May 2024 contained a Glossary of useful terms for the classification of ludi and games (p. 49-60), which brought together in a single sequence, for easier consultation, the definitions provided in the text of the Classification.
The Glossary published in print, however, had the limitation of not being easily updatable, both in the definitions provided in a lemma, and in the number of lemmas themselves. It was therefore decided to propose the Glossary in the form of an extraction from the Cla-G dataset, where the different entities are also defined through the "Author's definition" property and where the bibliographic reference to the source from which the definition was taken is provided. The Glossary is therefore an easy-to-consult tool, but also easy to update. At the moment, not all the Italian definitions are available in English.
N.B. The lemmas in the Glossary are repeated when more than one author's definition has been recorded for one lemma.
Launch the Glossary [in Italian!]
How to participate in Cla-G
The use of Cla-G, the dataset, and ClaG, the classification system on which it is based, requires skills in terms of both knowledge of the classification of games (ClaG), its criteria, rules and classification schedules, and knowledge of how the Wikibase user interface works.
These skills are not particularly complex, but it is essential that they are fully acquired by those who want to participate actively - in a personal or institutional capacity - in the development of the classification of games. For this reason, at the moment, accounts are created only for users who have followed a specific training course on ClaG and Cla-G. At the end of these training courses, organized by the Department of Musicology and Cultural Heritage of the University of Pavia, Italy - also in collaboration with other educational and training agencies - the certificate necessary to obtain an account on Cla-G is issued.
However, since Cla-G is freely available, those who are not registered as users can still search for their games in Cla-G, check if they have already been entered, and use the classification number to manage their collection. Furthermore, anyone can send a detailed description of a game and propose the relative classification number to be entered in Cla-G.
How to cite
To cite a single object (e.g. the item of a game or a person) in this dataset, use this citation style:
- ClaG Dataset (https://cla-g.wikibase.cloud/wiki/Item:QXX, ACCESS DATE), Label, identifier.
- For example:
- ClaG Dataset (https://cla-g.wikibase.cloud/wiki/Item:Q21, 21 August 2024), Stefano Bartezzaghi, Q21.
- ClaG Dataset (https://cla-g.wikibase.cloud/wiki/Item:Q148, 21 August 2024), Chess, Q148.
To cite the project and the website as a whole, use this reference:
- Carlo Bianchini, Cla-G. Classificazione dei giochi per ludoteche e biblioteche (https://cla-g.wikibase.cloud, 2024).
Bibliography
- Bianchini, Carlo, and Paolo Munini. Proposta per una classificazione dei giochi ad uso di Ludoteche e Biblioteche [i.e. Proposal for a classification of games for use in toy libraries and Libraries]. Preliminary edition. Udine: Comune di Udine, 2024. Print.
- Bianchini, Carlo, and Paolo Munini. «ClaG. Una classifcazione dei giochi per ludoteche e biblioteche». Biblioteche oggi 42, issue 7 (October) (2024): 48–61. Available in open access: http://www.bibliotecheoggi.it/rivista/article/view/1739/1778 [in Italian]
- First edition of ClaG: Bianchini, Carlo, and Paolo Munini. ClaG. Classificazione dei Giochi per ludoteche e biblioteche. Udine: Comune di Udine, 2024, 85 p. ISBN 978-8897360100. Print. Free of charge upon request (see below).
- Bianchini, Carlo, and Paolo Munini. «ClaG: A classification system for plays and games in toy libraries and libraries». JLIS.it 16, issue 1 (2025):72–89. Available in open access: https://jlis.fupress.net/index.php/jlis/article/view/624 [in English]
- The Italian edition of ClaG can be obtained free of charge upon email request at the following address: archiviodeigiochi(at)comune.udine.it
- The English edition of ClaG is in progress and will available asap.
General information about this dataset
Cla-G Data Usage and Reuse Policy
Unless otherwise specified, all content on this Wiki is licensed under CC BY-NC-SA 4.0.
By contributing to this wiki, you agree to reuse your contributions under the terms of the specified license.
Changes to this wiki are automatically saved (see the 'View History' tab on each page) and can be reviewed by the administrator if necessary. Any act of vandalism is prohibited and - frankly - unseemly.
Acknowledgements
We would like to thank Wikimedia Deutschland for developing, maintaining and supporting this vital infrastructure.
Publisher Declaration
This wiki is published by Carlo Bianchini, who is legally responsible for its content.