Main Page
ClaG: classificazione dei giochi per ludoteche e biblioteche
A partire da agosto 2024, Cla-G, questa istanza di Wikibase, è stata creata e gradualmente arricchita di linked data relativi alla ClaG. Classificazione dei giochi per ludoteche e biblioteche di Carlo Bianchini e Paolo Munini. La proposta è stata presentata:
- nell'ambito della fiera Modena Play nel maggio 2024 e
- al Dipartimento di Musicologia e Beni culturali di dell'Università di Pavia, con sede a Cremona.
Il dataset, in linea con i nostri valori, cresce in base alla collaborazione dei volontari che partecipano al progetto e costituisce uno strumento a disposizione gratuita di tutte le ludoteche e le biblioteche che vogliono adottare e utilizzare la classificazione ClaG. Questo significa che il nostro dataset è un 'organismo che cresce' e che, in ogni momento, la sua forma è da considerarsi provvisoria e perfettibile.
Obiettivi
Lo scopo di Cla-G si può riassumere, in modo non necessariamente esaustivo, facendo riferimento a tre possibili ambiti di interesse: quello di una specifica istituzione, quello di un responsabile della ludoteca o della biblioteca e quello della conoscenza generale del mondo dei giochi.
Rispetto a un’istituzione (una ludoteca o una biblioteca), i vantaggi dell’uso di Cla-G possono essere:
- avere a disposizione uno strumento di classificazione, collaborativo e partecipato tra tutte le ludoteche e le biblioteche interessate;
- la possibilità di creare, scaricare, condividere, pubblicare un elenco completo, navigabile e interattivo, dei giochi della propria collezione;
- utilizzare uno strumento avanzato basato sui LOD, che consente una navigazione reciproca tra il proprio OPAC e Cla-G nonché tra il proprio OPAC e Wikidata;
- aumentare, tramite la logica dei LOD, la visibilità e le possibilità di scoperta della propria collezione di giochi;
- creare una rete di persone, associazioni e istituzioni impegnate in questo ambito e favorire lo sviluppo della cooperazione e dello scambio di informazioni tra di esse.
Dal punto di vista del responsabile della ludoteca e della biblioteca, Cla-G costituisce uno strumento efficace per:
- classificare in modo facilitato i giochi della propria collezione, attraverso il processo guidato per la produzione di un numero di classe;
- organizzare fisicamente nello spazio a disposizione la propria collezione di giochi;
- avere a disposizione le Tavole di classificazione di ClaG in forma completa, gratuita e sempre aggiornata;
- imparare ad analizzare un gioco nelle sue caratteristiche fondamentali;
- gestire in modo scientifico l’interazione di reference, recuperando con maggiore facilità i giochi che hanno le caratteristiche richieste dai giocatori che entrano in ludoteca o in biblioteca;
- consultare il numero di classe assegnato a un gioco da parte di una istituzione;
- scoprire quali e quante istituzioni possiedono un determinato gioco.
Cla-G sarà infine uno strumento molto utile per la conoscenza dei giochi in generale, perché consentirà di:
- avere a disposizione uno strumento di consultazione libero e gratuito per la scoperta dei giochi esistenti (ovvero posseduti da tutte le istituzioni partecipanti);
- offrire uno strumento di scoperta ed esplorazione dei giochi in base alle loro caratteristiche (spazio di gioco, materiali, ambientazione, esito, genere ed età);
- creare un dataset che consenta di fare analisi quantitative sui giochi prodotti dal mercato;
- migliorare la capacità di controllo e verifica, e quindi la qualità, dei dati sui giochi;
- favorire il riuso dei dati relativi ai giochi e al loro numero di classificazione ClaG.
Volontari coinvolti
In questa sezione sono registrati i nomi di tutti i volontari e di tutte le istituzioni che collaborano, a vario titolo, alla creazione e al mantenimento dei dati di ClaG. La registrazione dei partecipanti ha la doppia funzione di riconoscere a ciascuno il lavoro svolto e di consentire il controllo della qualità dei contributi apportati (seguendo il link "vedi modifiche").
- Carlo Bianchini (Vedi modifiche)
- Camillo Pellizzari (Vedi modifiche)
- Claudia Mauro (AIG) (Vedi modifiche)
- Paolo Munini (Vedi modifiche)
- UgoScala (Vedi modifiche)
- SCUP in servizio alla Biblioteca comunale di Trento (Vedi modifiche)
Come iniziare a esplorare Cla-G
Ecco alcuni punti di partenza per iniziare a visualizzare i contenuti di questo wiki:
- Cercare qualche gioco che ci si aspetta di trovare (inserendo il nome nel box in alto a destra)
- Utilizzare alcune delle seguenti query già predisposte per avere un'idea dei dati raccolti e dei vantaggi nell'organizzazione dei giochi in base al numero di ClaG:
Tutti i giochi in ordine alfabetico
#title:Tutti i giochi in ordine alfabetico
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tutti i giochi da tavolo senza altro supporto in ordine alfabetico
#title:Tutti i giochi da tavolo senza altro supporto in ordine alfabetico
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P17 ld:Q41 .
# OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tutti i solitari classificati nel dataset
#title:Tutti i solitari classificati nel dataset
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass ?item WHERE {
?item ldt:P21 ld:Q111 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tutti i giochi di dadi tradizionali e speciali classificati nel dataset
#title:Tutti i giochi di dadi classificati nel dataset
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass ?item WHERE {
{ ?item ldt:P18 ld:Q75 .} UNION { ?item ldt:P18 ld:Q76 . } UNION { ?item ldt:P18 ld:Q77 . }
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tutti i giochi in ordine alfabetico posseduti dalla Biblioteca comunale di Trento
#title:Tutti i giochi in ordine alfabetico posseduti dalla Biblioteca comunale di Trento
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P26 ld:Q187 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Tutti i giochi in ordine alfabetico posseduti dalla Ludoteca comunale di Udine
#title:Tutti i giochi in ordine alfabetico posseduti dalla Ludoteca comunale di Udine
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?spazioLabel ?materialiLabel ?ambientazioneLabel ?esitoLabel ?genereLabel ?etàLabel ?numClass WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P26 ld:Q196 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
ORDER BY ?itemLabel
Tutti i giochi in ordine alfabetico che hanno uno o più ID dell'OPAC SBN FVG
#title:Tutti i giochi in ordine alfabetico che hanno uno o più ID dell'OPAC SBN FVG
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?itemLabel ?numClass ?item ?itemDescription ?sbnfvgID WHERE {
?item ldt:P1 ld:Q4 .
OPTIONAL { ?item ldt:P17 ?spazio . }
OPTIONAL { ?item ldt:P18 ?materiali }
OPTIONAL { ?item ldt:P20 ?ambientazione . }
OPTIONAL { ?item ldt:P21 ?esito . }
OPTIONAL { ?item ldt:P22 ?genere . }
OPTIONAL { ?item ldt:P23 ?età . }
OPTIONAL { ?item ldt:P24 ?numClass . }
?item ldt:P25 ?ID .
BIND(uri(concat("https://www.sbnfvg.it/?IDS=", ?ID)) as ?sbnfvgID)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
ORDER BY ?itemLabel
Query avanzate
Se volete estrarre una maggiore quantità di dati, o dati più complessi, potete provare una di queste query:
Visualizzazione del modello con grafi ad albero
Grafo ad albero delle sottoclassi di attività ludica
#title:Grafo ad albero delle sottoclassi di attività ludica
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q3 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q2) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero delle sottoclassi di spazio
#title:Grafo ad albero delle sottoclassi di spazio
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q23 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q23) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero delle sottoclassi di materiali
#title:Grafo ad albero delle sottoclassi di materiali
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q58 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q58) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero delle sottoclassi di ambientazione
#title:Grafo ad albero delle sottoclassi di ambientazione
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q91 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q91) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero delle sottoclassi di esito
#title:Grafo ad albero delle sottoclassi di esito
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q104 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q104) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Grafo ad albero delle classi dei giochi in base al genere
#title:Grafo ad albero delle classi dei giochi in base al genere
#defaultView:Graph
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?linkTo WHERE {
?item ldt:P2* ld:Q122 .
OPTIONAL { ?linkTo ldt:P2 ?item . FILTER(?linkTo != ld:Q3) } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?itemLabel
Query di conteggio
Numero di Giochi in base al genere ordinati per classificazione di genere
#title: Numero di Giochi in base al genere ordinati per classificazione di genere
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?genere ?genereLabel (COUNT(?item) AS ?count) WHERE {
?item ldt:P1 ld:Q4 . #Q4 è un gioco
?item ldt:P22 ?genere.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
GROUP BY ?genere ?genereLabel
ORDER BY ASC(?genereLabel)
Numero di classificazioni in base al numero decrescente di giochi associati
#title: Numeri di classificazione in base al numero decresente di giochi associati
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT ?numClass (COUNT(?item) AS ?count) WHERE {
?item ldt:P1 ld:Q4 . #Q4 è un gioco
?item ldt:P24 ?numClass .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
GROUP BY ?numClass ?numClassLabel
ORDER BY DESC(?count)
Query federate con Wikidata
Query dei giochi di Cla-G che hanno un'immagine su Wikicommons e ne sono privi su Cla-G
#title: Query dei giochi di Cla-G che hanno un'immagine su Wikicommons e ne sono privi su Cla-G
PREFIX ld: <https://cla-g.wikibase.cloud/entity/>
PREFIX ldt: <https://cla-g.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?wdlink ?wditem ?image WHERE {
?item ldt:P1 ld:Q4 . #Q4 Gioco
?item ldt:P3 ?wdlink . # Ricava l'ID del gioco in WD
FILTER NOT EXISTS { ?item ldt:P28 ?immagineClaG . }
BIND(URI(CONCAT("http://www.wikidata.org/entity/", STR(?wdlink))) AS ?wditem)
SERVICE <https://query.wikidata.org/sparql> { ?wditem wdt:P18 ?image . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
ORDER BY ?itemLabel
Utilizzo e riutilizzo dei dati
Ove non diversamente specificato, tutto il contenuto di questo Wiki è sotto una licenza CC BY-NC-SA 4.0.
Contribuendo a questo wiki, acconsenti a riutilizzare i tuoi contributi nei termini specificati nella [...] pagina della privacy.
Le modifiche a questo wiki sono salvate in modo automatico (vedi la linguetta 'Cronologia' presente in ogni pagina) e possono essere revisionate dall'amministratore in caso di necessità. Ogni atto di vandalismo è proibito e - sinceramente - disdicevole.
Query di servizio
Elenco degli item privi di etichetta in inglese
# Etichette in italiano e in inglese
#title: Etichette in italiano e in inglese
SELECT DISTINCT ?item ?LabelIT ?LabelEN WHERE {
?item ?p ?o .
?item rdfs:label ?LabelIT FILTER (lang(?LabelIT) = "it") .
FILTER NOT EXISTS { ?item rdfs:label ?LabelEN FILTER (lang(?LabelEN) = "en") . }
}
Il Glossario di ClaG
La Proposta per una classificazione dei giochi ad uso di Ludoteche e Biblioteche pubblicata in maggio 2024 integrava un Glossario dei termini utili per la classificazione dei ludi e dei giochi (p. 49-60), che riuniva in un'unica sequenza, per una più pronta consultazione, le definizioni fornite nel testo della Classificazione.
Il Glossario pubblicato a stampa, tuttavia, aveva il limite di non essere facilmente aggiornabile, sia nelle definizioni fornite in un lemma, sia nel numero dei lemmi stessi. Si è quindi pensato di proporre il Glossario sotto forma di estrazione dal dataset Cla-G, dove le diverse entità sono definite anche mediante la proprietà "Definizione d'autore" e il riferimento bibliografico alla fonte dalla quale la definizione è tratta. Il Glossario quindi è uno strumento di facile consultazione, ma anche di facile aggiornamento.
N.B. I lemmi del Glossario vengono ripetuti quando per un lemma sono state registrate più di una definizione d'autore.
Apri il Glossario
Come partecipare a Cla-G
L'uso di Cla-G, il dataset, e di ClaG, la classificazione su cui esso si basa, richiede competenze sia in termini di conoscenza della classificazione dei giochi (ClaG), dei suoi criteri, delle regole e delle tavole di classificazione sia una conoscenza del funzionamento dell'interfaccia utente di Wikibase. Queste competenze non sono particolarmente complesse, ma è indispensabile che siano pienamente acquisite da chi vuole partecipare in modo attivo - a titolo personale o istituzionale - allo sviluppo della classificazione dei giochi. Per questo motivo, l'account viene creato solo per gli utenti che hanno seguito un specifico corso di formazione su ClaG e su Cla-G. Al termine di questi corsi di formazione, organizzati dal Dipartimento di Musicologia e beni culturali dell'Università di Pavia - anche in collaborazione con altri centri di formazione - viene rilasciato il certificato necessario per ottenere un account su Cla-G.
Citazioni suggerite
Per citare un singolo oggetto (per es. un gioco o una persona) in questo dataset utilizzate questo stile citazionale:
- ClaG Dataset (https://cla-g.wikibase.cloud/wiki/Item:QXX, DATA DI ACCESSO), Etichetta, identificatore.
- Per esempio: ClaG Dataset (https://cla-g.wikibase.cloud/wiki/Item:Q21, 21 August 2024), Stefano Bartezzaghi, Q21.
Per citare il progetto e il sito web nel suo complesso, utilizzate questo riferimento bibliografico:
- Carlo Bianchini, Cla-G: classificazione dei giochi per ludoteche e biblioteche (https://cla-g.wikibase.cloud, 2024).
Per citare il sistema di classificazione, utilizzate uno dei seguenti riferimenti bibliografici:
- Bianchini, Carlo, e Paolo Munini. Proposta per una classificazione dei giochi ad uso di ludoteche e biblioteche. Edizione preliminare. Udine: Comune di Udine, 2024.
- Bianchini, Carlo, e Paolo Munini. «ClaG. Una classifcazione dei giochi per ludoteche e biblioteche». Biblioteche oggi 42, fasc. 7 (ottobre) (2024): 48–61. Disponibile in open access: http://www.bibliotecheoggi.it/rivista/article/view/1739/1778
- Bianchini, Carlo, e Paolo Munini. «ClaG: A classification system for plays and games in toy libraries and libraries». JLIS.it 16, fasc. 1 (in print).
Informazioni generali sul dataset
- Tutti gli elementi creati
- Tutte le proprietà create
- Tutti gli utenti
- Statistiche su questa istanza di Wikibase
Ringraziamenti
Ringraziamo Wikimedia Deutschland per lo sviluppo, il mantenimento e il supporto di questa infrastruttura di importanza fondamentale.
Publisher Declaration
Questo wiki è pubblicato da Carlo Bianchini, che è legalmente responsabile per il suo contenuto.